package demonchime

import "core:log"
import "core:math"
import "core:math/linalg"
import hm "core:container/handle_map"

import "fw"

Rope :: struct {
  handle: Handle,
  hanging_id: Image_Id,
  verlet: Verlet_Rope,
}

step_ropes :: proc(dt: f32) {
  iter := hm.iterator_make(&state.rope_list)
  for rope, _ in hm.iterate(&iter) {
    update_verlet_rope(&rope.verlet)
  }
}

draw_ropes :: proc() {
  iter := hm.iterator_make(&state.rope_list)
  for rope, _ in hm.iterate(&iter) {
    for i in 0..<len(rope.verlet.nodes) - 1 {
      cur := rope.verlet.nodes[i]
      nex := rope.verlet.nodes[i + 1]
      fw.draw_line(
        linalg.round(cur.pos),
        linalg.round(nex.pos),
        color = fw.rgba8(76, 62, 36),
      )
    }

    a := rope.verlet.nodes[len(rope.verlet.nodes) - 1]
    b := rope.verlet.nodes[len(rope.verlet.nodes) - 2]

    dir := b.pos - a.pos
    rotation := math.atan2(dir.y, dir.x) + math.PI / 2

    img := get_image(rope.hanging_id)
    fw.draw_tex_ex(
      img,
      a.pos,
      offset = linalg.round(Vec2{f32(img.size.x) * 0.5, 0}),
      rot = rotation,
    )
  }
}

clear_ropes :: proc() {
  iter := hm.iterator_make(&state.rope_list)
  for rope, _ in hm.iterate(&iter) {
    delete(rope.verlet.nodes)
  }

  hm.clear(&state.rope_list)
}

on_room_open_rope :: proc(room_id: Room_Id) {
  clear_ropes()
}

object_spawner_rope :: proc(obj: Object_Resource) {
  image_id, is_image_id := convert_path_to_resource(obj, "image").(Image_Id)
  if !is_image_id {
    image_id = .Small_Lamp
  }
  node_length := obj.properties["node_length"].(i32)
  length := obj.properties["length"].(i32)

  nodes := make([]Verlet_Node, length)
  for &node, i in nodes {
    node = create_verlet_node(
      obj.pos + Vec2{0, f32(i) * f32(node_length)},
      i == 0,
    )
  }


  verlet := Verlet_Rope{
    nodes = nodes,
    node_length = f32(node_length),
  }

  // Simulate a few steps to get rid of some silliness
  for _ in 0..<60 {
    update_verlet_rope(&verlet)
  }

  handle := hm.add(&state.rope_list, Rope{
    hanging_id = image_id,
    verlet = verlet,
  })
}